<<CheminPackLocaux`

§ 4	Distributions théoriques
	à une variable continue

Packages locaux

A partir de la commande  aide[], charger

<<Statistique`

<<Tableaux`

§ 4.1 	Distribution uniforme

Expérience aléatoire

Sur un cadran gradué en tours, on lance une aiguille pivotant autour du centre C qui, après quelques tours, s'arrête sur une position aléatoire décrite par un nombre réel de l'intervalle [0; 1[.

Show[Graphics[{Circle[{0,0},1],Text["C",{0,0},{-1,1}],Text["0.25",{0,1},{0,-1}],Text["0",{1,0},{-1,0}],Text["0.5",{-1,0},{1,0}],Text["0.75",{0,-1},{0,1}],Arrow[{{0,0},0.9` {-0.8`,0.6`}}]}],AspectRatio->Automatic,PlotRange->All,ImageSize->{300,200}]

Simulation et nombres pseudo-aléatoires

Remplaçons l'expérience par une simulation. Générons un échantillon de taille n :

n=40;

?UniformDistribution

?RandomReal

unif=UniformDistribution[{0,1}];

x=RandomReal[unif,n]

Comme dans une expérience aléatoire, une nouvelle exécution donne habituellement d'autres résultats

x=RandomReal[unif,n]

Probabilité

Notons X la variable aléatoire uniformément distribuée sur l'intervalle [0; 1[ et exprimons la probabilité que X appartienne à un intervalle donné

P[0.2≤X<0.3]=((0.3-0.2)/1)=(1/10)

P[0.2≤X<0.25]=((0.25-0.2)/1)=(1/20)

P[0.2≤X<0.201]=((0.201-0.2)/1)=(1/1000)

La probabilité de tirer exactement un nombre donné est nulle

P[X=0.201]=0

Lorsque la variable X est continue, on peut parler de la probabilité d'un intervalle, peu importe s'il est ouvert ou fermé

P[0.2≤X<0.3]=P[0.2<X<0.3]=P[0.2≤X≤0.3]

Modèle théorique

La distribution uniforme sur l'intervalle [a, b[ est caractérisée par son histogramme qui se réduit à un rectangle. L'aire du rectangle étant 1 et sa largeur b-a, sa hauteur est

(Subscript[h, 1])=(1/(b-a))

La fonction densité est donc

h(x)={({{({{(Subscript[h, 1]), pour a≤x<b}})}, {({{0,                 sinon}})}})

Voici par exemple deux histogrammes successifs
	le premier représente la distribution uniforme sur [0; 1[,
	le second la distribution uniforme sur [0; 3[.

histogramme[{0,1},{1},PlotRange->{{-0.5,3},{0,1}}, AxesLabel->{None,"Densité"}, AxesOrigin->{-0.5,0}]

histogramme[{0,3},{1},PlotRange->{{-0.5,3},{0,1}},AxesLabel->{None,"Densité"}, AxesOrigin->{-0.5,0}]

Remarquez que les aires sont toutes deux égales à 1. La fonction qui exprime les probabilités cumulées est appelé distribution. La distribution uniforme sur [0; 1[ est représentée ci-dessous en trait continu; la seconde, sur [0; 3[, en traitillé.

Show[frequenceCumuleeContinue[{0,1},{1}],Graphics[{Dashing[{0.01`}],First[frequenceCumuleeContinue[{0,3},{1}]]}],Ticks->Automatic,PlotRange->All,AxesLabel->{None,"Probabilité cumulée"}]

Remarquez que les distributions uniformes sont continues.

Espérance et écart-type de la distribution continue uniforme

Clear[a,b]

distr=UniformDistribution[{a,b}];

La moyenne de la distribution uniforme est la valeur centrale:

μ=Mean[distr]

Le calcul de l'écart-type des distributions continues dépasse les ambitions de ce cours. Mais le résultat nous sera utile:

V=Variance[distr]

Exercice 4.1 - 1

Dans le cas particulier de l'intervalle [a, b[=[0, 1[, déterminez la moyenne empirique m et la variance empirique (s^2) d'un échantillon obtenu par simulation.

Comparez les résultats obtenus avec l'espérance mathématique μ=E(X)=(1/2) et la variance théorique (σ^2)=V(X)=(1/12). Le but est de se convaincre que les résultats théoriques sont plausibles.

Facultativement : écrivez la limite à calculer pour obtenir la variance théorique.

§ 4.2 	Distribution normale

Introduction

D'une manière générale, la fonction densité h(x) se caractérise par sa moyenne, son écart-type et sa forme. La forme de h, c'est-à-dire son allure, peut être quelconque; en particulier, elle peut être symétrique ou asymétrique. Certaines formes particulières apparaissent souvent dans les applications ou dans les modèles mathématiques. La plus importante est la distribution normale dont la fonction de densité est aussi appelée "courbe en cloche de Gauss". Nous allons la construire en partant de la distribution binomiale.

Distribution binomiale

Partons du problème suivant
	on lance k fois un dé et on compte le nombre de six obtenus.
Les résultats possibles sont 0, 1, 2, ... k. La distribution est donc discrète.
Chaque issue a une probabilité déterminée

(Subscript[p, 0])=P{X=0}, ..., (Subscript[p, k])=P{X=k}

Nous avons déjà résolu  le problème dans le cas particulier k=3 (voir § 3.2). Comme il n'est pas dans l'objectif de ce cours de savoir calculer les probabilités par les mathématiques, nous nous contenterons ici de demander les résultats à Mathematica.

Distribution discrète

k=20;p=(1/6);
distr=BinomialDistribution[k,p];
c=Range[0,k];
freq=Table[PDF[distr,x],{x,0,k}];

diagrammeBatons[c,freq,AxesLabel->{None,"Probabilité"}]

L'espérance mathématique et l'écart-type théorique de la distribution binomiale sont donnés par les formules suivantes (qui seront démontrées dans Statistique II, § 2) :

μ=k p; N[μ]

σ=(Sqrt[k p (1-p)]);N[σ]

Transformation de la distribution binomiale en une distribution continue
ou distribution binomiale interpolée

Notre but étant de construire une distribution continue, nous allons commencer par rendre continue la distribution précédente. Utilisons la méthode qui consiste à "étaler" le bâton en j sur l'intervalle [j-(1/2), j+(1/2)[ avec la même fréquence (Subscript[f, j]). La densité correspondante sera donc (Subscript[h, j])=((Subscript[f, j])/1). La distibution obtenue s'appelle "distribution binomiale interpolée".

k=20;p=(1/6);
distr=BinomialDistribution[k,p];
b=Range[-(1/2),k+(1/2)];
freq=Table[PDF[distr,j],{j,0,k}];

histogramme[b,freq,AxesLabel->{None,"Densité de probabilité"}, AxesOrigin->{-3,0}]

k=45;p=(1/6);
distr=BinomialDistribution[k,p];
b=Range[-(1/2),k+(1/2)];
freq=Table[PDF[distr,j],{j,0,k}];

histogramme[b,freq,AxesLabel->{None,"Densité de probabilité"}, AxesOrigin->{-3,0}]

On peut observer que les densités ne sont pas symétriques par rapport à la moyenne, particulièrement lorsque k est petit.

Variables centrées réduites

Comment comparer les formes (ou allures) des deux distributions précédentes alors que leurs moyennes et leurs écart-types sont différents?

L'idée est de leur donner
	le même centre en leur soustrayant l'espérance mathématique et
	la même dispersion en divisant par l'écart-type :

Z=((X-μ)/σ)                          où            μ=E(X)      et      (σ^2)=V(X)

On obtient alors une nouvelle distribution appelée centrée réduite dont l'espérance mathématique est nulle (voir les propriétés de E dans le § 3.4)

E(Z)=E(((X-μ)/σ)  )=E((1/σ) X-(μ/σ))=(1/σ)E(X)-(μ/σ)=(1/σ)μ-(μ/σ)=0

et dont la variance est 1 (voir les propriétés de V dans § 3.4)

V(Z)=V(((X-μ)/σ)  )=V((1/σ) X-(μ/σ))=(1/(σ^2))V(X)=(1/(σ^2))(σ^2)=1

Comparons les deux histogrammes:

k=20;p=(1/6);
distr=BinomialDistribution[k,p];
b=Range[-(1/2),k+(1/2)];
freq1=Table[PDF[distr,j],{j,0,k}];
μ=k p;
σ=(Sqrt[k p (1-p)]);
z1=((b-μ)/σ);
k=45;p=(1/6);
distr=BinomialDistribution[k,p];
b=Range[-(1/2),k+(1/2)];
freq2=Table[PDF[distr,j],{j,0,k}];
μ=k p;
σ=(Sqrt[k p (1-p)]);
z2=((b-μ)/σ);
GraphicsRow[{histogramme[z1,freq1, PlotRange->{{-4,4},All},AxesOrigin->{-3.5,0},ImageSize->{200,120}],histogramme[z2,freq2, PlotRange->{{-4,4},All},AxesOrigin->{-3.5,0},ImageSize->{200,120}]}]

Exercice 4.2 - 1         [Sans ordinateur]

Un étudiant a obtenu 5.2 à l'examen final de mathématiques pour lequel la moyenne était de 4.8 et l'écart-type de 0.5.

A l'examen final de physique, dont la moyenne était de 5.1 et l'écart-type de 0.8, il a obtenu 5.5.

Dans quelle discipline était-il relativement meilleur ?

Indication : comparez les variables centrées réduites.

Distribution normale (0, 1)

Pour une valeur plus grande de k, la fonction densité de la distibution binomiale interpolée tend vers une courbe qui est pratiquement symétrique par rapport à la moyenne

k=180;p=(1/6);
distr=BinomialDistribution[k,p];
b=Range[-(1/2),k+(1/2)];
freq=Table[PDF[distr,j],{j,0,k}];
μ=k p;
σ=(Sqrt[k p (1-p)]);
z=((b-μ)/σ);
histogramme[z,freq,PlotRange->{{-4,4},All}, AxesLabel->{None,"Densité de probabilité"}, AxesOrigin->{-3.5,0}]

Les mathématiciens démontrent que, quel que soit p, la densité de la distribution binomiale tend vers une courbe bien définie appelée courbe en cloche ou courbe de Gauss dont l'expression mathématique est

ϕ(x)=(1/(Sqrt[2 π]))(e^(-((x^2)/2)))

distr=NormalDistribution[0,1];
Plot[PDF[distr,x],{x,-4,4},PlotStyle->Black,ImageSize->{400,200}, AxesLabel->{None,"Densité de probabilité"}]

Superposons les deux derniers graphiques

Show[histogramme[z,freq],Plot[PDF[distr,t],{t,-4,4}, PlotStyle->{Black,Thick}],PlotRange->{{-4,4},All},AxesOrigin->{-3.5,0},AxesLabel->{None,"Densité de probabilité"}]

Si k p≥5 et k (1-p)≥5 alors la distribution normale constitue une bonne approximation de la distribution binomiale.

Distribution normale (μ, σ)

Si Z désigne la distribution normale (0, 1) c'est-à-dire avec E(Z)=0 et V(Z)=1,
alors la variable  X=σ Z+ μ   a la distribution normale (μ, σ) car

E(X)=E(σ Z+μ)=σ E(z)+μ=σ 0+μ=μ
V(X)=V(σ Z+μ)=(σ^2) V(Z)=(σ^2)1= (σ^2)

Les distributions normales constituent une famille dont on peut choisir librement l'espérance mathématique μ et l'écart-type théorique σ.

μ=4;σ=1;distr=NormalDistribution[μ,σ];
Plot[PDF[distr,x],{x,μ-4 σ,μ+4 σ},Ticks->{{{μ-3 σ,"μ-3σ"},{μ-2 σ,"μ-2σ"},{μ-σ,"μ-σ"},{μ,"μ"},{μ+σ,"μ+σ"},{μ+2 σ,"μ+2σ"},{μ+3 σ,"μ+3σ"}},Automatic},PlotStyle->Black,ImageSize->{300,200}, AxesLabel->{None,"Densité de probabilité"}]

Puisque cette courbe est une densité, l'aire de la surface comprise entre la courbe et l'axe horizontal est 1.
A titre d'exemple, superposons cette courbe avec la distribution binomiale (20;(1/6)) interpolée:

k=20;p=(1/6);
b=Range[-(1/2),k+(1/2)];
freq=Table[PDF[BinomialDistribution[k,p],c],{c,0,k}];
μ=k p;
σ=(Sqrt[k p (1-p)]);
Show[histogramme[b,freq],Plot[PDF[NormalDistribution[μ,σ],x],{x,First[b]-2,Last[b]+2},PlotStyle->{Black,Thick}],AxesLabel->{None,"Densité de probabilité"}, AxesOrigin->{-3.5,0}]

Rôle de    μ=E(X)
Graphiquement, une augmentation de l'espérance mathématique se traduit par une translation de la densité vers la droite (courbe en traitillé)

μ=65;σ=7;distr=NormalDistribution[μ,σ];
distr2=NormalDistribution[μ+σ,σ];
Plot[{PDF[distr,t],PDF[distr2,t]},{t,45,95},PlotStyle->{{Black,Dashing[{}]},{Black,Dashing[{0.02`}]}},Ticks->{Range[40,100,5],Automatic},PlotRange->All,ImageSize->{400,200},AxesLabel->{"Masse [kg]","Densite [\!\(\*FractionBox[\(1\), \(kg\)]\)]"}]

Rôle de   σ=(Sqrt[V(X)])
Graphiquement, une augmentation de l'écart-type théorique se traduit par un étalement de la densité c'est-à-dire une augmentation de la dispersion (courbe en traitillé). Rappelons que l'aire de la surface emprisonnée entre la courbe et l'axe horizontal est égale à 1.

distr3=NormalDistribution[μ,((3 σ)/2)];
Plot[{PDF[distr,t],PDF[distr3,t]},{t,30,100},PlotStyle->{{Black,Dashing[{}]},{Black,Dashing[{0.02`,0.01`}]}},Ticks->{Range[30,100,10],Automatic},ImageSize->{400,200},AxesLabel->{"Masse [kg]","Densite [\!\(\*FractionBox[\(1\), \(kg\)]\)]"}]

Probabilité d'un intervalle

Rappels

Pour les distributions empiriques, nous avons vu, dans le § 2.1, que la distribution est liée à la fréquence par les relations

F(x)=f(]-∞,x])

f(]a,b])=F(b)-F(a)

Cette dernière relation peut s'interpréter comme représentant l'aire de la surface délimitée par la fonction densité au-dessus de l'intervalle ]a, b] (voir fig. dans le § 2.1).

Distribution et densité normales

Les distributions théoriques entretiennent les mêmes relations avec les probabilités. Notons  Φ la fonction de distribution normale et ϕ la fonction densité normale. La valeur de la distribution en x est égale à la probabilité de l'événement ]-∞, x].

Φ(x)=P]-∞,x]

Plot[CDF[NormalDistribution[0,1],x],{x,-4,4}, PlotStyle->Black]

Graphiquement, la fonction de distribution en x s'interprète comme l'aire de la surface située au-dessus de l'intervalle ]-∞,x] et délimitée par la fonction densité.

μ=4;σ=1;distr=NormalDistribution[μ,σ];a=μ-4 σ;b=μ-0.5` σ;
Show[Plot[PDF[distr,t],{t,μ-4 σ,μ+4 σ},PlotStyle->Black],Plot[PDF[distr,t],{t,a,b},Filling->0,FillingStyle->GrayLevel[0]],Ticks->{{{b,"x"}},Automatic},Epilog->{{Dashing[{0.01`,0.01`}],Line[{{a,0},{a,PDF[distr,a]}}],Line[{{b,0},{b,PDF[distr,b]}}]}},ImageSize->{400,200}]

La probabilité d'un intervalle peut se déduire de la fonction distribution

P(]a,b])=Φ(b)-Φ(a)

Graphiquement, la probabilité d'un intervalle s'interprète comme l'aire de la surface située au-dessus de l'intervalle et délimitée par la fonction densité.

μ=4;σ=1;distr=NormalDistribution[μ,σ];a=μ-1.5` σ;b=μ-0.5` σ;
Show[Plot[PDF[distr,t],{t,μ-4 σ,μ+4 σ}, PlotStyle->Black],Plot[PDF[distr,t],{t,a,b},Filling->0,FillingStyle->GrayLevel[0]],Ticks->{{{a,"a"},{b,"b"}},Automatic},Epilog->{{Dashing[{0.01`,0.01`}],Line[{{a,0},{a,PDF[distr,a]}}],Line[{{b,0},{b,PDF[distr,b]}}]}},ImageSize->{400,200}]

Calculons la probabilité de l'événement X appartient à l'intervalle ]μ-σ, μ+σ] :

P]μ-σ,μ+σ]=P]-∞,μ+σ]  -  P]-∞,μ-σ]=Φ(μ+σ)-Φ(μ-σ)

distr=NormalDistribution[0,1];
N[CDF[distr,1]-CDF[distr,-1]]

Cette probabilité est d'environ 68.27 %.

μ=4;σ=1;distr=NormalDistribution[μ,σ];
Show[Plot[PDF[distr,t],{t,μ-σ,μ+σ},Filling->0,FillingStyle->GrayLevel[0.85]],Plot[PDF[distr,x],{x,μ-4 σ,μ+4 σ},PlotStyle->Black],Ticks->{{{μ-3 σ,"μ-3σ"},{μ-σ,"μ-σ"},{μ,"μ"},{μ+σ,"μ+σ"},{μ+3 σ,"μ+3σ"}},Automatic},Epilog->{Line[{{μ-σ,0},{μ+σ,0}}],{Dashing[{0.01`,0.01`}],Line[{{μ-σ,0},{μ-σ,PDF[distr,μ-σ]}}],Line[{{μ+σ,0},{μ+σ,PDF[distr,μ+σ]}}]},Text["68.27 %",{μ,0.1`}]},ImageSize->{400,200}, PlotRange->{{μ-4σ,μ+4σ},All}, AxesOrigin->{μ-3.5σ,0}, AxesLabel->{None, "Densité"}]

Calculons la probabilité de l'événement X appartient à l'intervalle ]μ -2 σ, μ + 2 σ ]

P]μ-2σ,μ+2σ]=P]-∞,μ+2σ]  -  P]-∞,μ-2σ]=Φ(μ+2σ)-Φ(μ-2σ)

distr=NormalDistribution[0,1];
N[CDF[distr,2]-CDF[distr,-2]]

Cette probabilité est d'environ 95.45 %.

μ=4;σ=1;distr=NormalDistribution[μ,σ];
Show[Plot[PDF[distr,t],{t,μ-2 σ,μ+2 σ},Filling->Axis,FillingStyle->GrayLevel[0.85]],Plot[PDF[distr,x],{x,μ-4 σ,μ+4 σ},PlotStyle->Black],Ticks->{{{μ-2 σ,"μ-2σ"},{μ,"μ"},{μ+2 σ,"μ+2σ"}},Automatic},Epilog->{Line[{{μ-2 σ,0},{μ+2 σ,0}}],{Dashing[{0.01`,0.01`}],Line[{{μ-2 σ,0},{μ-2 σ,PDF[distr,μ-2 σ]}}],Line[{{μ+2 σ,0},{μ+2 σ,PDF[distr,μ+2 σ]}}]},Text["95.45 %",{μ,0.1`}]},ImageSize->{400,200}, PlotRange->{{μ-4σ,μ+4σ},All}, AxesOrigin->{μ-3.5σ,0}, AxesLabel->{None, "Densité"}]

Calculons la probabilité de l'événement X appartient à l'intervalle ]μ -3 σ, μ + 3 σ ]

P]μ-3σ,μ+3σ]=P]-∞,μ+3σ]  -  P]-∞,μ-3σ]=Φ(μ+3σ)-Φ(μ-3σ)

distr=NormalDistribution[0,1];
N[CDF[distr,3]-CDF[distr,-3]]

Cette probabilité est d'environ 99.73 %.

μ=4;σ=1;distr=NormalDistribution[μ,σ];
Show[Plot[PDF[distr,t],{t,μ-3 σ,μ+3 σ},Filling->Axis,FillingStyle->GrayLevel[0.85]],Plot[PDF[distr,x],{x,μ-4 σ,μ+4 σ},PlotStyle->Black],Ticks->{{{μ-3 σ,"μ-3σ"},{μ,"μ"},{μ+3 σ,"μ+3σ"}},Automatic},Epilog->{Line[{{μ-3 σ,0},{μ+3 σ,0}}],{Dashing[{0.01`,0.01`}],Line[{{μ-3 σ,0},{μ-3 σ,PDF[distr,μ-3 σ]}}],Line[{{μ+3 σ,0},{μ+3 σ,PDF[distr,μ+3 σ]}}]},Text["99.73 %",{μ,0.1`}]},ImageSize->{400,200}, PlotRange->{{μ-4σ,μ+4σ},All}, AxesOrigin->{μ-3.5σ,0}, AxesLabel->{None, "Densité"}]

Retenons la règle des 3 σ
	la quasi totalité des observations sont situées dans l'intervalle ]μ - 3 σ, μ + 3 σ ].

Exercice 4.2 - 2         [Avec Mathematica]

Nous nous proposons de comparer une distribution binomiale et une distribution normale.

On lance k pièces de monnaie (k=32) et on compte le nombre de "pile" obtenus.
Dressez un diagramme à bâtons des fréquences observées.

Pour p=(1/2), dessinez le graphique de la densité de probabilité de la distribution normale μ=k p  et σ=(Sqrt[k p(1-p)]).

Superposez les deux graphiques dans un même repère (Remarque : lorsque tous les écarts entre deux modalités successives sont égaux à 1, on peut interpréter le diagramme à bâtons comme un histogramme.)

Exercice 4.2 - 3           [Avec Mathematica]

a)	Considérons le nombre moyen de six obtenus en lançant 100 fois le dé. 
	Cette variable aléatoire, désignée par (Subscript[M, 100]), est (Subscript[M, 100])=(1/100) S où 
	S est la distribution binomiale (100, (1/6)).
	Tracez l'histogramme de la distribution théorique. Comparez avec la distribution normale.
	Remarque : pour la variable (Subscript[M, 100]), l'écart entre deux modalités successives est (1/100), raison pour
	laquelle on ne peut pas simplement superposer le diagramme à bâtons et la fonction de densité.
	Le procédé d'interpolation contourne la difficulté.

b)	Effectuons maintenant une simulation de (Subscript[M, 100]). On demande de
	 - construire un échantillon de taille n;
	 - grouper les données en les traitant comme une variable continue;
	 - superposer l'histogramme et la distribution normale.

Exercice 4.2 - 4           [Avec Mathematica]

Pour illustrer graphiquement la notion d'écart-type, considérons deux variables aléatoires continues qui obéissent à des distributions normales. Imaginons deux populations (infinies) dont on mesure la masse de chaque individu. Les moyennes des deux populations sont égales à 60 kg. L'écart-type de la première est de 2 kg tandis que l'écart-type de la deuxième est de 10 kg.

a)	Dans un même graphique, superposez les densités des deux populations.

b)	Effectuez un tirage aléatoire de 100 personnes de chaque population.

Exercice 4.2 - 5           [Avec Mathematica]

a)	On donne un échantillon a dont les données ont été groupées:

Une distribution normale est-elle un modèle acceptable pour a ?

Indication : utilisez une méthode graphique.

b)	On donne un échantillon b dont les données ont été groupées:

Une distribution normale est-elle un modèle acceptable pour b ?

Exercice 4.2 - 6           [Avec Mathematica]

Le diamètre intérieur moyen d'un échantillon de rondelles produites par une machine est de 1.275 cm et l'écart-type de 0.013 cm. L'usage que l'on en fait nécessite que le diamètre soit situé entre les bornes de tolérance de 1.260 à 1.290 cm sans quoi les rondelles sont considérées comme défectueuses.

Déterminez le pourcentage de rondelles défectueuses en supposant que les diamètres sont normalement distribués.

Exercice 4.2 - 7           [Avec Mathematica]

On a lancé 500 fois une pièce de monnaie parfaitement équilibrée.

a)	Répondez à la question suivante en approximant la distribution binomiale au moyen d'une distribution normale: quelle est la probabilité que le nombre de faces soit situé entre 240 et 260 inclusivement ?

b)	Comparez avec l'exercice 3.2-3.

§ 4.3	Autres distributions

Exercice 4.3-1          [Avec Mathematica]

Une fabrique produit deux modèles d'appareils:
		30 % de modèle A
		70 % de modèle B.
Le modèle A a une durée de vie uniformément distribué sur l'intervalle [3 ans; 8 ans[ tandis que le modèle B a une durée de vie uniformément distribué sur l'intervalle [2 ans; 6 ans[.

a)	Calculez l'espérance mathématique μ.
	Représentez la fonction densité de la distribution théorique

b)	A partir d'un grand échantillon, calculez la moyenne et l'écart-type empiriques de la variable
	aléatoire "durée de vie d'un appareil".

Indications:
(3/10)des appareils dans [3; 8[ et (7/10)dans [2; 6[ équivaut à
			(7/10)·(1/4) des appareils dans [2; 3[
			(3/10)·(3/5)+(7/10)·(3/4) des appareils dans [3; 6[
			(3/10)·(2/5) des appareils dans [6, 8[
Il s'agit donc de définir une variable aléatoire qui est
			uniformément distribuée dans [2, 3[ avec une probabilité de (7/40)
			uniformément distribuée dans [3, 6[ avec une probabilité de (141/200)
			uniformément distribuée dans [6, 8[ avec une probabilité de (3/25).

Pour choisir dans lequel des trois cas on tombe, on commence par tirer une variable aléatoire uniformément distribuée sur l'intervalle [0, 1[. Pour une question d'efficacité, on commence par traiter le cas le plus fréquent:
	cas [3, 6] avec la prob.			 (141/200)=0.705
	cas [3, 6] ou [2, 3] avec la prob.   	(141/200)+(7/40)=0.88

va[]:=Module[{z},
		z=Random[UniformDistribution[{0,1}]];
	Which[z<0.705,Random[UniformDistribution[{3,6}]],
	                z<0.88,Random[UniformDistribution[{2,3}]],
			    True, Random[UniformDistribution[{6,8}]]]]

n=40;

x=Table[va[],{n}]

§ 4.4 	Estimation des paramètres

Dans ce paragraphe, nous nous demandons si les paramètres empiririques m et s permettent d'estimer les paramètres théoriques μ et σ.

Revenons à notre problème "Masses corporelles d'étudiants"  du § 2.1. A en juger par son histogramme, il paraît plausible que la distribution théorique soit normale. Pour passer d'une distribution empirique à la distribution théorique normale, il reste encore à estimer les paramètres μ et σ.

Estimation de l'espérance mathématique

Nous montrerons, dans Statistique II, § 2.5, qu'un bon estimateur de l'espérance mathématique est la moyenne empirique. Nous avons vu, dans le § 2, que l'on obtient des moyennes un peu différentes selon les groupements effectués. En prenant la moyenne des données brutes:

(Overscript[μ, ∧])=m=(1/n)(∑_(i=1)^n)(Subscript[x, i   ])

x={69,59,70,72,67,49,69,67,62,65,60,68,71,75,62,77,74,59,65,62,67,74,54,63,54,69,61,72,65,54,62,71,71,74,80,61,80,67,65,65,69,69,77,62,73,61,58,77,59,73,73,66,62,57,55,61,62,67,57,55,61,67,79,69,64,70,68,68,59,67,67,64,77,73,67,57,66,68,72,78,75,62,55,64,62,71,66,67,70,68,52,77,60,65,61,57,58,70,69,66,76,69,67,63,77,77,69,72,66,60,65,62,65,61,66,72,73,76,61,63,66,64,65,61,64,61,70,66,60,65,67,56,67,66,73,70,73,73,68,64};

n=Length[x]

μ=Mean[x];N[μ]

Exercice 4.4 - 1                      [Sans ordinateur]

Démontrez que la valeur de t pour laquelle la fonction suivante est minimale

t↦(1/n)(∑_(i=1)^n)((((Subscript[x, i])-t))^2)

est la moyenne arithmétique

t=m=(1/n)(∑_(i=1)^n)(Subscript[x, i])

Indication : la fonction à étudier est du deuxième degré en t.

Estimation de l'écart-type théorique

L'écart-type empirique est calculée par rapport à la moyenne empirique

s=(Sqrt[(1/n)(∑_(i=1)^n)((((Subscript[x, i])-m))^2)])

Parmi tous les nombres m, c'est la moyenne arithmétique qui rend l'expression précédente minimale. Si maintenant on veut calculer l'écart type par rapport à l'espérance mathématique, on obtiendra un résultat plus grand

(Sqrt[(1/n)(∑_(i=1)^n)((((Subscript[x, i])-μ))^2)])

L'écart entre m et μ peut être important, particulièrement pour de petits échantillons. L'écart-type empirique s est généralement plus petit que l'écart-type théorique σ. On dit que s est un estimateur biaisé de σ.

Nous montrerons, dans Statistique II, § 2.5, qu'on obtient un estimateur non biaisé en remplaçant n par (n-1) dans la formule, c'est-à-dire

(Overscript[σ, ∧])=(Sqrt[(1/(n-1))(∑_(i=1)^n)((((Subscript[x, i])-m))^2)])

La correction est sensible pour de petits échantillons mais elle est négligeable pour les grands.

Il est nécessaire de calculer l'écart-type sur les mêmes données que celles utilisées pour calculer la moyenne (les deux paramètres avec les données brutes ou les deux paramètres avec les données groupées).

σ=StandardDeviation[x];N[σ]

Modèle théorique

Pour l'exemple "Masses corporelles d'étudiants" du § 2.1, la distribution théorique est la suivante

distr=NormalDistribution[μ,σ];

Superposons les graphiques empiriques et théoriques

b={44.5`,54.5`,59.5`,64.5`,69.5`,74.5`,79.5`,89.5`};
effectifs={5,14,33,47,26,13,2};
freq=(effectifs/n);
Show[histogramme[b,freq],Plot[PDF[distr,t],{t,Min[b],Max[b]}, PlotStyle->{Black,Thick}], AxesLabel->{None,"Densité"}, PlotRange->All, AxesOrigin->{40,0}]

Puisque la superposition est excellente, l'hypothèse "la distribution est normale" est raisonnable. On dit alors que l'on a ajusté les données par une loi normale.

Exercice 4.4 - 2

On donne l'échantillon suivant:

x={95,84,76,82,87}

a)	[Sans ordinateur] Calculez la moyenne et l'écart-type empiriques.
 b)	[Avec Mathematica] Calculez la moyenne et l'écart-type empiriques.
 c)	[Sans ordinateur] Estimez l'espérance (Overscript[μ, ∧]) et l'écart-type théorique (Overscript[σ, ∧]).
 d)	[Avec Mathematica] Estimez l'espérance (Overscript[μ, ∧]) et l'écart-type théorique (Overscript[σ, ∧]).